mirror of
https://github.com/empayre/fleet.git
synced 2024-11-07 09:18:59 +00:00
d650423be0
Added reference architectures using https://docs.gitlab.com/ee/administration/reference_architectures/ as inspiration. - updated terraform based on some feedback of usage - pinned fleet docker version in terraform as to no get unexpected upgrades when applying - updated some documentation around apply migration tasks
47 lines
1.3 KiB
HCL
47 lines
1.3 KiB
HCL
resource "aws_route53_zone" "dogfood_fleetdm_com" {
|
|
name = var.domain_fleetdm
|
|
}
|
|
|
|
resource "aws_route53_record" "dogfood_fleetdm_com" {
|
|
zone_id = aws_route53_zone.dogfood_fleetdm_com.zone_id
|
|
name = var.domain_fleetdm
|
|
type = "A"
|
|
|
|
alias {
|
|
name = aws_alb.main.dns_name
|
|
zone_id = aws_alb.main.zone_id
|
|
evaluate_target_health = false
|
|
}
|
|
}
|
|
|
|
resource "aws_acm_certificate" "dogfood_fleetdm_com" {
|
|
domain_name = var.domain_fleetdm
|
|
validation_method = "DNS"
|
|
|
|
lifecycle {
|
|
create_before_destroy = true
|
|
}
|
|
}
|
|
|
|
resource "aws_route53_record" "dogfood_fleetdm_com_validation" {
|
|
for_each = {
|
|
for dvo in aws_acm_certificate.dogfood_fleetdm_com.domain_validation_options : dvo.domain_name => {
|
|
name = dvo.resource_record_name
|
|
record = dvo.resource_record_value
|
|
type = dvo.resource_record_type
|
|
}
|
|
}
|
|
|
|
allow_overwrite = true
|
|
name = each.value.name
|
|
records = [each.value.record]
|
|
ttl = 60
|
|
type = each.value.type
|
|
zone_id = aws_route53_zone.dogfood_fleetdm_com.zone_id
|
|
}
|
|
|
|
resource "aws_acm_certificate_validation" "dogfood_fleetdm_com" {
|
|
certificate_arn = aws_acm_certificate.dogfood_fleetdm_com.arn
|
|
validation_record_fqdns = [for record in aws_route53_record.dogfood_fleetdm_com_validation : record.fqdn]
|
|
}
|